receive_check.ino

이 파일의 문서화 페이지로 가기

 
#include "minimac.h"
#include <EEPROM.h>
#include <SPI.h>
#include <mcp_can.h>

#define PROTECTED_ID 0x123

const uint8_t SECRET_KEY[MINIMAC_KEY_LEN] = {0x1A, 0x2B, 0x3C, 0x4D, 0x5E, 0x6F,
                                             0x70, 0x81, 0x92, 0xA3, 0xB4, 0xC5,
                                             0xD6, 0xE7, 0xF8, 0x09};

MCP_CAN CAN(10);

void setup() {
  Serial.begin(115200);
  while (!Serial)
    ;
 
  // EEPROM 전체 초기화
  for (int i = 0; i < EEPROM.length(); i++) {
    EEPROM.write(i, 0xFF);
  }
 
  // CAN 초기화 (all IDs, 500kbps, 16MHz)
  if (CAN.begin(MCP_ANY, CAN_500KBPS, MCP_16MHZ) != CAN_OK) {
    Serial.println("[ERROR] CAN Init Failed!");
    for (;;)
      ;
  }
  CAN.setMode(MCP_NORMAL);
 
  // Mini-MAC 초기화 (fresh 상태로 시작)
  minimac_init(PROTECTED_ID, SECRET_KEY);
 
  Serial.println("[INFO] Receiver Initialized");
}

void loop() {
  // 메시지 도착 체크
  if (CAN.checkReceive() != CAN_MSGAVAIL) {
    delay(10);
    return;
  }
 
  // 메시지 읽기
  unsigned long rxId;
  uint8_t len;
  uint8_t buf[MINIMAC_MAX_DATA + MINIMAC_TAG_LEN];
  CAN.readMsgBuf(&rxId, &len, buf);
 
  Serial.print("[DBG] CAN received ID=0x");
  Serial.print(rxId, HEX);
  Serial.print(" len=");
  Serial.println(len);
 
  // ID 검증
  if (rxId != PROTECTED_ID) {
    Serial.println("[DBG] Ignored (unprotected ID)");
    return;
  }
  if (len < MINIMAC_TAG_LEN) {
    Serial.println("[ERROR] Frame too short");
    return;
  }
 
  // 페이로드/태그 분리
  uint8_t payloadLen = len - MINIMAC_TAG_LEN;
  uint8_t payload[MINIMAC_MAX_DATA];
  uint8_t tag[MINIMAC_TAG_LEN];
  memcpy(payload, buf, payloadLen);
  memcpy(tag, buf + payloadLen, MINIMAC_TAG_LEN);
 
  // 디버그: payload
  Serial.print("[DBG] payload = ");
  for (uint8_t i = 0; i < payloadLen; i++) {
    if (payload[i] < 0x10)
      Serial.print('0');
    Serial.print(payload[i], HEX);
    Serial.print(' ');
  }
  Serial.println();
 
  // 디버그: recv tag
  Serial.print("[DBG] recv tag = ");
  for (uint8_t i = 0; i < MINIMAC_TAG_LEN; i++) {
    if (tag[i] < 0x10)
      Serial.print('0');
    Serial.print(tag[i], HEX);
    Serial.print(' ');
  }
  Serial.println();
 
  // 검증
  Serial.println("[DBG] minimac_verify()");
  if (minimac_verify(payload, payloadLen, tag)) {
    Serial.println("[INFO] Auth OK");
  } else {
    Serial.println("[ERROR] Auth FAIL");
  }
}